GitHub

Fitting Interferometric Observables

In this tutorial, we fit a planet & orbit model to a sequence of interferometric observations. Closure phases and squared visibilities are supported.

We load the observations in OI-FITS format and model them as a point source orbiting a star.

Note

Interferometer modelling is supported in Octofitter via the extension package OctofitterInterferometry. To install it, run pkg> add http://github.com/sefffal/Octofitter.jl:OctofitterInterferometry

using Octofitter
using OctofitterInterferometry
using Distributions
using CairoMakie
using PairPlots
┌ Warning: Module Octofitter with build ID ffffffff-ffff-ffff-0000-00a6ce1adcbe is missing from the cache.
│ This may mean Octofitter [daf3887e-d01a-44a1-9d7e-98f15c5d69c9] does not support precompilation but is imported by a module that does.
└ @ Base loading.jl:1948

Download simulated JWST AMI observations from our examples folder on GitHub:

download("https://github.com/sefffal/Octofitter.jl/raw/main/examples/AMI_data/Sim_data_2023_1_.oifits", "Sim_data_2023_1_.oifits")
download("https://github.com/sefffal/Octofitter.jl/raw/main/examples/AMI_data/Sim_data_2023_2_.oifits", "Sim_data_2023_2_.oifits")
download("https://github.com/sefffal/Octofitter.jl/raw/main/examples/AMI_data/Sim_data_2024_1_.oifits", "Sim_data_2024_1_.oifits")
"Sim_data_2024_1_.oifits"

Create the likelihood object:

vis_like = InterferometryLikelihood(
    (; filename="Sim_data_2023_1_.oifits", epoch=mjd("2023-06-01"), spectrum_var=:contrast_F480M, use_vis2=false),
    (; filename="Sim_data_2023_2_.oifits", epoch=mjd("2023-08-15"), spectrum_var=:contrast_F480M, use_vis2=false),
    (; filename="Sim_data_2024_1_.oifits", epoch=mjd("2024-06-01"), spectrum_var=:contrast_F480M, use_vis2=false),
)
OctofitterInterferometry.InterferometryLikelihood Table with 14 columns and 3 rows:
     filename              epoch    spectrum_var    use_vis2  ⋯
   ┌───────────────────────────────────────────────────────────
 1 │ Sim_data_2023_1_.oi…  60096.0  contrast_F480M  false     ⋯
 2 │ Sim_data_2023_2_.oi…  60171.0  contrast_F480M  false     ⋯
 3 │ Sim_data_2024_1_.oi…  60462.0  contrast_F480M  false     ⋯

Plot the closure phases:

fig = Makie.Figure()
ax = Axis(
    fig[1,1],
    xlabel="index",
    ylabel="closure phase",
)
Makie.stem!(
    vis_like.table.cps_data[1][:],
    label="epoch 1",
)
Makie.stem!(
    vis_like.table.cps_data[2][:],
    label="epoch 2"
)
Makie.stem!(
    vis_like.table.cps_data[3][:],
    label="epoch 3"
)
Makie.Legend(fig[1,2], ax)
fig
Example block output
@planet b Visual{KepOrbit} begin
    a ~ truncated(Normal(2,0.1), lower=0)
    e ~ truncated(Normal(0, 0.05),lower=0, upper=0.90)
    i ~ Sine()
    ω ~ UniformCircular()
    Ω ~ UniformCircular()

    # Our prior on the planet's photometry
    # 0 +- 10% of stars brightness (assuming this is unit of data files)
    contrast_F480M ~ truncated(Normal(0, 0.1),lower=0)

    θ ~ UniformCircular()
    tp = θ_at_epoch_to_tperi(system,b,60171)  # reference epoch for θ. Choose an MJD date near your data.
end

@system Tutoria begin
    M ~ truncated(Normal(1.5, 0.01), lower=0)
    plx ~ truncated(Normal(100., 0.1), lower=0)
end vis_like b
System model Tutoria
Derived:
  
Priors:
  M	Truncated(Distributions.Normal{Float64}(μ=1.5, σ=0.01); lower=0.0)
  plx	Truncated(Distributions.Normal{Float64}(μ=100.0, σ=0.1); lower=0.0)
Planet b
Derived:
  ω, Ω, θ, tp, 
Priors:
  a	Truncated(Distributions.Normal{Float64}(μ=2.0, σ=0.1); lower=0.0)
  e	Truncated(Distributions.Normal{Float64}(μ=0.0, σ=0.05); lower=0.0, upper=0.9)
  i	Sine()
  ωy	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
  ωx	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
  Ωy	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
  Ωx	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
  contrast_F480M	Truncated(Distributions.Normal{Float64}(μ=0.0, σ=0.1); lower=0.0)
  θy	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
  θx	Distributions.Normal{Float64}(μ=0.0, σ=1.0)
Octofitter.UnitLengthPrior{:ωy, :ωx}: √(ωy^2+ωx^2) ~ LogNormal(log(1), 0.02)
Octofitter.UnitLengthPrior{:Ωy, :Ωx}: √(Ωy^2+Ωx^2) ~ LogNormal(log(1), 0.02)
Octofitter.UnitLengthPrior{:θy, :θx}: √(θy^2+θx^2) ~ LogNormal(log(1), 0.02)


OctofitterInterferometry.InterferometryLikelihood Table with 14 columns and 3 rows:
     filename              epoch    spectrum_var    use_vis2  ⋯
   ┌───────────────────────────────────────────────────────────
 1 │ Sim_data_2023_1_.oi…  60096.0  contrast_F480M  false     ⋯
 2 │ Sim_data_2023_2_.oi…  60171.0  contrast_F480M  false     ⋯
 3 │ Sim_data_2024_1_.oi…  60462.0  contrast_F480M  false     ⋯

Create the model object and run octofit_pigeons:

model = Octofitter.LogDensityModel(Tutoria)

using Pigeons
results,pt = octofit_pigeons(model, n_rounds=10);
[ Info: Determining initial positions and metric using pathfinder
┌ Info: Found a sample of initial positions
└   initial_logpost_range = (161.61990614922573, 178.21820663016962)
────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────
  scans     restarts      Λ        Λ_var      time(s)    allc(B)  log(Z₁/Z₀)   min(α)     mean(α)    min(αₑ)   mean(αₑ)
────────── ────────── ────────── ────────── ────────── ────────── ────────── ────────── ────────── ────────── ──────────
        2          0        4.6       4.94       6.69    1.3e+09  -1.72e+03          0      0.692      0.939      0.965
        4          0        4.3       4.95       1.61   1.47e+09       -326          0      0.701      0.894      0.927
        8          0       4.83       4.38       2.36   2.37e+09      -65.5  2.16e-211      0.703      0.907      0.928
       16          0       5.66        5.6       4.73   4.76e+09        173   8.91e-24      0.637      0.889      0.917
       32          0        6.1       6.28        9.5   9.57e+09        178    0.00356      0.601      0.902      0.918
       64          7       6.31       2.55       20.9   2.01e+10        176      0.143      0.714      0.907      0.923
      128         12       6.48       2.61       39.7   3.98e+10        176     0.0997      0.707      0.908      0.923
      256         25       6.71       2.62       78.2   7.82e+10        176      0.288      0.699       0.91      0.921
      512         63       6.95       2.73        156   1.57e+11        176      0.452      0.688      0.908       0.92
 1.02e+03        148       6.77       2.66        317   3.16e+11        176      0.518      0.696      0.909       0.92
────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────

Note that we use Pigeons paralell tempered sampling (octofit_pigeons) instead of HMC (octofit) because interferometry data is almost always multi-modal (or more precisely non-convex, there is often still a single mode that dominates).

Examine the recovered photometry posterior:

hist(results[:b_contrast_F480M][:], axis=(;xlabel="F480M"))
Example block output

Determine the significance of the detection:

using Statistics
phot = results[:b_contrast_F480M][:]
snr = mean(phot)/std(phot)
7.276898550901578

Plot the resulting orbit:

octoplot(model, results)
Example block output

Plot only the position at each epoch:

using PlanetOrbits
els = Octofitter.construct_elements(results,:b,:);
fig = Makie.Figure()
ax = Makie.Axis(
    fig[1,1],
    autolimitaspect = 1,
    xreversed=true,
    xlabel="ΔR.A. (mas)",
    ylabel="ΔDec. (mas)",
)
for epoch in vis_like.table.epoch
    Makie.scatter!(
        ax,
        raoff.(els, epoch)[:],
        decoff.(els, epoch)[:],
        label=string(mjd2date(epoch)),
        markersize=1.5,
    )
end
Makie.Legend(fig[1,2], ax, "date")
fig
Example block output

Finally we can examine the joint photometry and orbit posterior as a corner plot:

using PairPlots
using CairoMakie: Makie
octocorner(model, results)
Example block output